Macros en Excel: qué son, ejemplos y cómo crearlas con VBA

Una macro es una serie de instrucciones guardadas que Excel ejecuta por ti: dar formato a un reporte, copiar datos de una hoja a otra, generar un PDF por cliente. Se escriben en VBA (Visual Basic for Applications), un lenguaje de programación incluido en Excel para Windows y Mac. Es la última pieza para pasar de usuario avanzado a la persona que automatiza el trabajo de su equipo.

Preparar Excel

1. Muestra la pestaña Programador: Archivo → Opciones → Personalizar cinta de opciones → marca Programador.
2. Guarda los libros con macros como .xlsm (Libro de Excel habilitado para macros). Un .xlsx no puede contener macros: si lo guardas así, se borran.

Tu primera macro grabada

La grabadora convierte tus clics en código, sin escribir nada:

1. Programador → Grabar macro. Nómbrala sin espacios, por ejemplo FormatoReporte. Puedes asignarle un atajo como Ctrl + Mayús + R.
2. Haz las acciones: pon en negrita la fila 1, aplica relleno de color, ajusta el ancho de columnas, aplica formato de moneda a la columna D, inmoviliza la fila superior.
3. Programador → Detener grabación.

Abre otro reporte con la misma estructura y ejecuta la macro (Programador → Macros → Ejecutar o con el atajo). Excel repite todo en un segundo.

Referencias absolutas o relativas

Por defecto, la grabadora registra celdas exactas (A1, D2…). Si activas Usar referencias relativas antes de grabar, registra movimientos relativos a la celda donde estés ("una a la derecha, dos abajo"). Es la misma idea que las referencias de la lección 3, aplicada a acciones.

El editor de VBA

Pulsa Alt + F11 (o Programador → Visual Basic). En la carpeta Módulos verás el código grabado. Será algo parecido a esto, aunque más largo, porque la grabadora registra todo:

Sub FormatoReporte()
    Rows("1:1").Font.Bold = True
    Range("A1:F1").Interior.Color = RGB(31, 78, 121)
    Range("A1:F1").Font.Color = RGB(255, 255, 255)
    Columns("A:F").AutoFit
    Columns("D:D").NumberFormat = "$#,##0.00"
End Sub

Cómo leerlo:

• Sub ... End Sub delimita la macro.
• Range("A1:F1") es un rango; Rows y Columns, filas y columnas.
• Después del punto vienen las propiedades: .Font.Bold, .Interior.Color, .Value…
• En VBA los formatos y las funciones van en inglés, con coma como separador, aunque tu Excel esté en español.

Escribir macros: variables, bucles y condiciones

La grabadora no sabe repetir ni decidir. Para eso se escribe código. Si hiciste el curso de Python, reconocerás todas las ideas.

Marcar facturas vencidas

Supón una hoja con la fecha de vencimiento en la columna D y quieres escribir "Vencida" en la E cuando la fecha ya pasó:

Sub MarcarVencidas()
    Dim fila As Long
    Dim ultima As Long

    ultima = Cells(Rows.Count, "A").End(xlUp).Row   ' última fila con datos

    For fila = 2 To ultima
        If Cells(fila, "D").Value < Date Then
            Cells(fila, "E").Value = "Vencida"
            Cells(fila, "E").Font.Color = RGB(192, 0, 0)
        Else
            Cells(fila, "E").Value = "Al día"
        End If
    Next fila

    MsgBox "Revisadas " & (ultima - 1) & " facturas."
End Sub

• Dim declara variables; Long es un número entero grande.
• Cells(fila, "D") es la celda de esa fila en la columna D.
• End(xlUp) equivale a Ctrl + ↑ desde el final de la hoja: encuentra la última fila con datos, aunque la lista crezca.
• Date es la fecha de hoy, como HOY().
• El apóstrofo ' inicia un comentario.

Usar funciones de Excel dentro de VBA

Dim total As Double
total = WorksheetFunction.Sum(Range("D2:D500"))
Range("H1").Value = total

Una hoja por región

Ejemplo más avanzado: crear una hoja con los datos de cada región a partir de la lista de ventas (columna B = región).

Sub HojaPorRegion()
    Dim datos As Worksheet, nueva As Worksheet
    Dim region As Variant
    Set datos = Worksheets("Ventas")

    For Each region In Array("Norte", "Sur", "Centro")
        Set nueva = Worksheets.Add(After:=Worksheets(Worksheets.Count))
        nueva.Name = region
        datos.Range("A1").CurrentRegion.AutoFilter Field:=2, Criteria1:=region
        datos.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible).Copy nueva.Range("A1")
        datos.AutoFilterMode = False
    Next region
End Sub

Ejecutar macros cómodamente

• Botón en la hoja: Insertar → Formas, dibuja un rectángulo, clic derecho → Asignar macro.
• Atajo de teclado: en Macros → Opciones.
• Libro de macros personal: al grabar, elige guardar en Libro de macros personal para tener la macro disponible en todos tus archivos.

¿Macros, Power Query o algo más?

Resumen del curso

• Básico: organización de datos, fórmulas, referencias, formato y tablas.
• Intermedio: SI, BUSCARV y BUSCARX, SUMAR.SI.CONJUNTO, validación y protección.
• Avanzado: tablas dinámicas, matrices dinámicas, Power Query y macros.

¡Felicidades, terminaste el curso de Excel! Con lo que sabes ya cubres lo que piden la mayoría de ofertas que exigen "Excel avanzado". Marca las lecciones como completadas para descargar tu certificado. Si quieres seguir, el siguiente paso natural es el análisis de datos con Python.